Output validation with XSLT 2.0

An interesting example occurred to me, about Schema-aware XSLT stylesheet design. Below is the code for it.

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema"
     version="2.0">
       
  <xsl:output method="xml" indent="yes" />
  
  <xsl:import-schema>
    <xs:schema>
      <xs:element name="x">
        <xs:complexType>      
          <xs:sequence>
            <xs:element name="y" />
          </xs:sequence>      
        </xs:complexType>
      </xs:element>
    </xs:schema>
  </xsl:import-schema>
  
  <xsl:import-schema>
    <xs:schema>
      <xs:element name="p">
        <xs:complexType>      
          <xs:sequence>
            <xs:element name="q" />
          </xs:sequence>      
        </xs:complexType>
      </xs:element>
    </xs:schema>
  </xsl:import-schema>
  
  <xsl:template match="/">
    <xsl:variable name="temp1">
      <x xsl:validation="strict">
        <y/>
      </x>
    </xsl:variable>
    <xsl:variable name="temp2">
      <p xsl:validation="strict">
        <q/>
      </p>
    </xsl:variable>
    <result>
      <xsl:copy-of select="$temp1" />
      <xsl:copy-of select="$temp2" />
    </result>
  </xsl:template>

</xsl:stylesheet>

This stylesheet imports/declares two inline XSD schemas. In the body of the root template, two variables (temp1 and temp2) request strict validation of the element markup.

If we run this example with a Schema-aware XSLT 2.0 processor, we can find that invalid content cannot be generated from the stylehseet.

An alternate writing style for the above example could be:

 <xsl:template match="/">
   <xsl:variable name="temp1">
     <x>
       <y/>
     </x>
   </xsl:variable>
   <xsl:variable name="temp2">
     <p>
       <q/>
     </p>
   </xsl:variable>
   <result>
     <xsl:copy-of select="$temp1" validation="strict" />
     <xsl:copy-of select="$temp2" validation="strict" />
   </result>
 </xsl:template>

Now we specify validation="strict" option on xsl:copy-of instruction.

The intended meaning is same in both the above cases.

This to me is quite useful XSLT facility. XSLT 2.0 is very flexible, where we want the validation in output tree to occur.